加更1_PLC Broker 要不要完整支持 MQTT 5.0？工业现场别被“新版本”带偏

MQTT 5.0

20 02 00 00

20 03 00 00 00

IF byProtocolLevel = 5 THEN
    xOk := F_MqttSkipVariableByteInteger(
        aBuffer := aRxBuf,
        uiOffset := uiOffset,
        uiBufferLen := uiFrameLen);

    IF NOT xOk THEN
        eParseError := E_MqttBrokerError.uiMalformedPacket;
        RETURN;
    END_IF
END_IF

/// =======================================================================
/// 名称      : F_MqttSkipVariableByteInteger
/// 功能      : 跳过 MQTT 变长整数编码字段
/// 说明      : MQTT 5.0 属性长度采用变长整数编码，当前轻量兼容层只需要校验并跳过该长度字段。
/// 编程人员  : ControlRookie
/// 时间      : 2026-05-08
/// 版本      : V1.0
/// =======================================================================
{attribute 'hide_all_locals'}
FUNCTION F_MqttSkipVariableByteInteger : BOOL
VAR_INPUT
    uiBufferLen  : UINT; // 当前 MQTT 完整报文长度或可用缓冲长度[byte]
END_VAR
VAR_IN_OUT
    aBuffer      : ARRAY[*] OF BYTE; // MQTT 原始报文缓冲区
    uiOffset     : UINT; // 输入为变长整数起始偏移，成功后推进到变长整数之后[byte]
END_VAR
VAR_OUTPUT
    udiValue     : UDINT; // 解码出的变长整数数值，MQTT 5.0 属性长度使用该值[byte]
END_VAR
VAR
    udiMultiplier : UDINT; // MQTT 变长整数倍率，依次为 1、128、16384、2097152
    byEncoded     : BYTE; // 当前读取的编码字节
    uiLoop        : UINT; // 变长整数最多允许 4 个字节
END_VAR

// === IMPLEMENTATION ===
udiValue := 0;
udiMultiplier := 1;

IF uiOffset >= uiBufferLen THEN
    F_MqttSkipVariableByteInteger := FALSE;
    RETURN;
END_IF

FOR uiLoop := 1 TO 4 DO
    IF uiOffset >= uiBufferLen THEN
        F_MqttSkipVariableByteInteger := FALSE;
        RETURN;
    END_IF

    byEncoded := aBuffer[uiOffset];
    udiValue := udiValue + TO_UDINT(byEncoded AND 16#7F) * udiMultiplier;
    uiOffset := uiOffset + 1;

    IF (byEncoded AND 16#80) = 0 THEN
        F_MqttSkipVariableByteInteger := TRUE;
        RETURN;
    END_IF

    udiMultiplier := udiMultiplier * 128;
END_FOR

F_MqttSkipVariableByteInteger := FALSE;

CASE ePacketType OF
    E_MqttPacketType.byConnAck:
        IF byProtocolLevel = GVL_MqttBroker.cnMqttProtocolLevel5 THEN
            udiNeededLen := 5;
        ELSE
            udiNeededLen := 4;
        END_IF

        IF (TO_UDINT(uiWriteOffset) + udiNeededLen) > udiBufferSize THEN
            M_BuildSimpleAck := FALSE;
            RETURN;
        END_IF
        aBuffer[uiWriteOffset] := TO_BYTE(E_MqttPacketType.byConnAck);
        aBuffer[uiWriteOffset + 2] := 0;
        aBuffer[uiWriteOffset + 3] := byReturnCode;
        IF byProtocolLevel = GVL_MqttBroker.cnMqttProtocolLevel5 THEN
            // MQTT 5.0 CONNACK = Acknowledge Flags + Reason Code + Properties。
            // 当前轻量兼容层不返回任何属性，因此属性长度固定写 0。
            aBuffer[uiWriteOffset + 1] := 3;
            aBuffer[uiWriteOffset + 4] := 0;
            uiFrameLen := 5;
        ELSE
            aBuffer[uiWriteOffset + 1] := 2;
            uiFrameLen := 4;
        END_IF