第2篇_写 MQTT Broker，第一关不是 PUBLISH，而是怎么让多个客户端稳稳连上同一个端口

xBrokerError = FALSE
eBrokerError = uiClientSlotsFull

// 1. 顶层只负责发现新连接和寻找空闲槽位。
uiFreeSlot := M_FindFreeConnectionSlot();

// 2. 找到槽位后，把 TCP 连接句柄交给对应连接 FB。
aConnections[uiFreeSlot].M_Attach(
    hConnection := hLastAcceptHandle,
    udiNowMs := udiNowMs);

// 3. 后续读写和 MQTT 会话状态都由该槽位独立维护。
aConnections[uiFreeSlot]();

/// =======================================================================
/// 名称      : M_AcceptNewConnection
/// 功能      : 接受一个新的 TCP 客户端连接
/// 说明      : 每扫描周期最多分配一个新连接，避免大量接入瞬间拖长 PLC 扫描周期。
/// 编程人员  : ControlRookie
/// 时间      : 2026-05-08
/// 版本      : V1.0
/// =======================================================================
{attribute 'hide_all_locals'}
METHOD M_AcceptNewConnection : BOOL
VAR
    uiIndex : UINT; // 连接槽位扫描索引[1..cnMaxClientSlots]
END_VAR

// === IMPLEMENTATION ===
uiFreeSlot := 0;
uiUsedSlotCount := 0;
xTcpAcceptActive := FALSE;
xTcpAcceptError := FALSE;

// 每个客户端槽位必须独立调用自己的 NBS.TCP_Connection。
// 之前如果多个槽位复用一个 TCP_Connection 实例，hConnection 会被后续接入覆盖，
// 连接槽位中的 TCP_Read 就可能读到已经失效或不属于自己的句柄，现场表现为客户端连接瞬间掉线。
FOR uiIndex := 1 TO GVL_MqttBroker.cnMaxClientSlots DO
    IF aConnections[uiIndex].xActive THEN
        // 已占用槽位继续保持对应 TCP_Connection 运行，用它的 xActive 作为该槽位连接是否仍有效的唯一依据。
        uiUsedSlotCount := uiUsedSlotCount + 1;
        aTcpAccept[uiIndex](xEnable := TRUE, hServer := hServer);
    ELSE
        IF uiFreeSlot = 0 THEN
            // 本周期只开放第一个空闲槽位接收新连接，控制 PLC 单周期接入工作量。
            uiFreeSlot := uiIndex;
            aTcpAccept[uiIndex](xEnable := TRUE, hServer := hServer);
        ELSE
            // 其他空闲槽位禁用，避免同一扫描周期多个空槽同时竞争同一个新连接。
            aTcpAccept[uiIndex](xEnable := FALSE, hServer := hServer);
        END_IF
    END_IF
END_FOR

/// =======================================================================
/// 名称      : M_Attach
/// 功能      : 把 TCP 连接句柄绑定到当前槽位
/// 说明      : 监听层接受新连接后调用，连接进入等待 MQTT CONNECT 状态。
/// 编程人员  : ControlRookie
/// 时间      : 2026-05-08
/// 版本      : V1.0
/// =======================================================================
{attribute 'hide_all_locals'}
METHOD M_Attach : BOOL
VAR_INPUT
    hConnection : NBS.CAA.HANDLE; // 新接入客户端的 TCP 连接句柄
END_VAR

// === IMPLEMENTATION ===
M_Reset();

IF hConnection = 0 THEN
    eLastError := E_MqttBrokerError.uiTcpAcceptFailed;
    M_Attach := FALSE;
    RETURN;
END_IF

stConnection.xUsed := TRUE;
stConnection.xMqttConnected := FALSE;
stConnection.xCleanSession := TRUE;
stConnection.xDisconnectRequested := FALSE;
stConnection.xGracefulDisconnect := FALSE;
stConnection.eState := E_MqttConnectionState.iWaitConnect;
stConnection.eLastError := E_MqttBrokerError.uiNoError;
stConnection.hConnection := hConnection;
stConnection.uiSlot := uiSlot;
stConnection.uiKeepAlive := GVL_MqttBroker.cnDefaultKeepAlive;
stConnection.udiLastActivityMs := udiNowMs;
stConnection.udiLastTcpActiveMs := udiNowMs;
stConnection.udiConnectedAtMs := 0;
stConnection.uiNextPacketId := 1;
eLastError := E_MqttBrokerError.uiNoError;
M_Attach := TRUE;